Objective

I will show you a method which makes it possible to look into the future from Easylanguage. Of course we show this method only educational to show traders the possibility of such things in Easylanguage. This should prevent novice traders blindly believe other peoples black-box codes.

Requirements

I am using SharedVar in my test but this could be also another DLL based tool which can cache future bars in memory or on disk. What we basically do is to store the future into the memory and look at them from past(bars). Is it such easy.

Get started

After reading about SharedVar library which makes it possible to cache all kind of data (string,boolean,double,integer) and lookup. Best part is that SV makes it possible doing this across all kind of trading tools, this tool is not made only for specific platform.

I would like to post following code, this code is very basic to understand:

external: "SharedVar-a32.dll", int,		"svInit"		,string;
external: "SharedVar-a32.dll", bool,	"svSetValue"	,int,string,double;
external: "SharedVar-a32.dll", bool,	"svSetString"	,int,string,string;
external: "SharedVar-a32.dll", double,	"svGetDouble"	,int,string;
external: "SharedVar-a32.dll", string,	"svGetString"	,int,string;
external: "SharedVar-a32.dll", bool,	"svServerStart";

Vars: maxbarsahead(10),qq(0),intrabarpersist atr(0),tradeok(false);
Vars: intrabarpersist sv(0);

method double getclose(int id)
begin
	return(svGetDouble(sv,NumtoStr(Barnumber+id,0)));
end;



Once begin
	svServerStart();
	sv=svInit("PerfectSystem");
	atr=AvgTrueRange(14);	
end;


svSetValue(sv,NumtoStr(Barnumber,0),Close);

if(sv>=0) then
begin
tradeok=false; 
For qq=1 to maxbarsahead 
Begin
	Value1=getclose(qq);	

	// check tp
	if (Value1>0 and Value1>Close+atr) then
	begin
		tradeok=true;		
		break;
	end;
	
	// check sl
	if (Value1>0 and Value1<Close-atr) then
	begin
		tradeok=false;
		break;
	end;
	
End;
If (tradeok) then Buy at this bar on close;
end;

rr
Setstopcontract;
Setprofittarget(atr);
setstoploss(atr*2);

What we do is to store all Close prices into SharedVar cache and lookup to future by next execution of strategy. First execution of Strategy does not generate any trades because we dont have any cached data, but if you refresh the chart second time you will have data to lookup from future and it starts working. Our strategy is basically trying to takeprofit ATR(14). I have used EURUSD,15min of 1 full year for my test, but this strategy would deliver perfect equity line on all possible timeframes and symbols. Holy Grail is found.

Why

I want to show everyone that everything is possible if you purchase a black-box! Creative coders might make similar holy grail like strategies easly, even in Trading platforms such as Tradestation or Multicharts. The smarter black-box-developer will mix holy-grail-like trading with some loosing streaks, this means the strategy more trusted because too-straigt-equity may not be seen very trusted from most of traders. Generally avoid all kind of blackbox trading systems

Howto Export in proper format

I had introduced fastappender in my previous posts, we will use this in order to archive speed. You could of course also skip this and modify my code to use Fileappend command, it would work but just very slow.

We will export the data as .csv format with ‘;’ seperation. Format will be Date;Time;Open;High;Low;Close;Volume

Inputs: ExportDirectory("c:\DATA1\");

Vars: OHLC("");
Vars: intrabarpersist FN(""),BInterval(0),intrabarpersist fa(0),string thetime("");

// External Definitions
external: "fast_appender.dll", int, "faInitA",LPSTR,int; 
external: "fast_appender.dll", int, "faAppendA",int,LPSTR; 

Once Begin
	if BarType=1 then BInterval=BarInterVal;
	if BarType=2 then BInterval=24*60; 
	if BarType=3 then BInterval=24*60*7;
	if BarType=4 then BInterval=24*60*30;
	If BarType=12 then BInterval=(Range/1 Point);
	FN=ExportDirectory+getsymbolname+"-"+Numtostr(BInterval,0)+".csv";
	fa=faInitA(FN,1);  	
end;

// Adjust time to HH:mm format
if (time>=1000) then	thetime=numtostr(time,0)   else
if (time>=100)  then    thetime="0"+numtostr(time,0) else
if (time>=10)   then  thetime="00"+numtostr(time,0) else thetime="000"+numtostr(time,0);
thetime=midstr(thetime,1,2)+":"+midstr(thetime,3,2);


OHLC=ELDateToString(Date)+";"+thetime+";"
		+Numtostr(o,6)+";"
		+Numtostr(h,6)+";"
		+Numtostr(l,6)+";"
		+Numtostr(c,6)+";"
		+Numtostr(Volume,1)+Newline;
 
faAppendA(fa,OHLC);

The output looks like this:

Volume is 0 because it is forex symbol, this code can export any symbol. This code assumes you have c:\DATA1\ directory exists, if not you can adjust this directory by Input parameter in Easylanguage code. Now we have a valid .csv file of 1 month

Import Custom Data into StrateyQuant

Start StrategyQuant, Click to Data Manager, make sure you are inside “History Data”, click to “Add Symbol”. You need to know the properties of Symbol you are importing. Especially Data type is very important.

This step has added a new symbol into Strategy Quant. Now we need to add Data to that recently added Symbol, to do this you first select new symbol and click to “Import Data” button.

Select Fileformat as shown on picture and make sure columns are labelled like seen on picture and press Start Import. StrategyQuant will confirm how many bars have been imported and you will have new data available:

Important

Version 3.8 does not support Tradestation Data compression into other Timeframes. They plan to support automatically create other Timeframes automatically. But for 3.8 version you have to import every Timeframe manually.

Compatibility

This library is not dedicated for Tradestation. It will work with every other platform such as Multicharts, Ninjatrader, C#. Our demonstration here is just for demo.

Details

Lets imagine you want to export OHLC Data as CSV to be able to analyse from an external tool. The problem is that Fileappend will be very slow operating, this is probably because Tradestation has only single command (its easy to handle) to Append and it probably does open and close by every single line and this requires time.

If we wanted export all Bar OHLC Data as external .csv file we need a code like seen:

// code snipplet
OHLC="ohlc=O="+Numtostr(o,6)+";"
		+"H="+Numtostr(h,6)+";"
		+"L="+Numtostr(l,6)+";"
		+"C="+Numtostr(c,6)+";"
		+"DATE="+Numtostr(Date,0)+";"
		+"TIME="+Numtostr(TIME,0)+";"		
		+"VOLUME="+Numtostr(Volume,1)+";"+Newline;

Fileappend(FN,OHLC);

Exporting 1 Year of M1 Data contains around 726000 Bars in Tradestation (EURUSD), to export all these bars Fileappend() needs 65 seconds to complete the operation (at least on my very fast computer with Flash/SSD Harddisk). If you need to export 10 years of data it would require over 12 minutes to complete, not very efficient.

Solution Approach

I have developed a library called fast_appender.dll, this library is allowed to accept lines to append, it does not open, close by every single append operation. It opens the file and keeps appending until you say to close.

The import is like seen:

external: "fast_appender.dll", string, "faVersionA";  
external: "fast_appender.dll", int, "faInitA",LPSTR,int; 
external: "fast_appender.dll", int, "faAppendA",int,LPSTR; 
external: "fast_appender.dll", int, "faClose",int;

I have made tests for both variants to append, with fileAppend native command of Easylanguage and FastAppender Library:

As you see FastAppender is over 5 times faster in appending to text files. 5 times speed improvement is not something you should underestimate, there is huge difference between 5 seconds and 25 seconds per chart and symbol and exported file.

FastAppender

int faInitA(string Filename,bool Append)

This is first function you need to call and call it only once (once begin….end block) at start. First parameter is name of file, second parameter accepts either 0 (false) or 1 (true), if you call it with 1, it will Append to existing file, if you call it with 0, it will Overwrite file and start Appending from first byte. This function returns a handle as int, you need to remember this handle, it will be reused in other commands

int faAppendA(int Handle,string LineToAppend)

This function will append LineToAppend to previously opened File, the Handle is taken from faInitA.

int faClose(int Handle)

This closes the handle, you will not need this function in Multicharts / Tradestation, you can need this function if you need to call from other platforms. Once you close the handle, you also close the file and you cannot Append anymore. If you are sure you will not append anymore, then you can close it.

string faVersionA()

Returns Version information of library.

Demonstration

This example exports OHLC Data of all bars as .csv file

Inputs: ExportDirectory("c:\DATA1\");
Vars: OHLC(""),intrabarpersist FN(""),BInterval(0),intrabarpersist fa(0);

// Import fast_appender
external: "fast_appender.dll", string, "faVersionA";  
external: "fast_appender.dll", int, "faInitA",LPSTR,int; 
external: "fast_appender.dll", int, "faAppendA",int,LPSTR; 
external: "fast_appender.dll", int, "faClose",int;

Once Begin
	if BarType=1 then BInterval=BarInterVal;
	if BarType=2 then BInterval=24*60; 
	if BarType=3 then BInterval=24*60*7;
	if BarType=4 then BInterval=24*60*30;
	If BarType=12 then BInterval=(Range/1 Point);	
	FN=ExportDirectory+getsymbolname+"-"+Numtostr(BInterval,0)+".csv";	
	// open File Handle and remember Handle in fa variable
	fa=faInitA(FN,1);  
end;

OHLC="ohlc=O="+Numtostr(o,6)+";"
		+"H="+Numtostr(h,6)+";"
		+"L="+Numtostr(l,6)+";"
		+"C="+Numtostr(c,6)+";"
		+"DATE="+Numtostr(Date,0)+";"
		+"TIME="+Numtostr(TIME,0)+";"		
		+"VOLUME="+Numtostr(Volume,1)+";"+Newline;
 
if (fa>0) then faAppendA(fa,OHLC);

Download

You can download it here

Final Words

FastAppender library is working with threads, you submit the data which needs to be appended and it will do the actual work in background to ensure speed. This library is over 5x faster than native command. It replaces native Fileappend command completely, you can use it for all your Append, Export operations.Have fun using it